# Generate a font with glyphs which have vertical glyph representations (but
# don't include the vertical glyph representations itself). This is used by
# the perl script `makefdx.pl' to create an FDX file as used by the CJK
# package for LaTeX.
#
# The font is created in the current directory.
#
# $1: The master font (e.g., `bsmi00lp.ttf').
# $2: The name of the target font (e.g., `bsmilpvr').

if ($argc != 3)
  Print("usage: [fontforge -script] ", $0, " master-font fontname");
  Quit(1);
endif;

Print("Loading ", $1, "...");
Open($1);

fontname = $2;
fullname = $fullname + " vertical reference";
copyright = $copyright \
            + Chr(10) + Chr(10) \
            + "Vertical glyph reference font version 2005-07-01.";
SetFontNames(fontname, "", fullname, "", copyright, "");

SelectByATT("Substitution", "vert", "", 1);
SelectInvert();
DetachAndRemoveGlyphs();

Print("Ensure third order curves...");
SetFontOrder(3);

Print("Scaling to PostScript units...");
ScaleToEm(900, 100);

num_chars = CharCnt();
count = 0;
delta = 100;

while (count + delta < num_chars)
  Print(count, "/", num_chars - 1, ":");
  Select(count, count + delta);

  Print("  Add extrema...");
  AddExtrema();

  Print("  Simplifying outlines...");
  Simplify(0, 2);

  count += delta;
endloop;

Print(count, "/", num_chars - 1, ":");
Select(count, num_chars - 1);

Print("  Add extrema...");
AddExtrema();

Print("  Simplifying outlines...");
Simplify(0, 2);

Reencode("original");

# generate AFM and TFM files, no PS hints, and rounded PS coordinates
Print("Generating font...");
Generate($2 + ".pfb", "", \
         0x1 | 0x100 | 0x10000 | 0x80000 | 0x200000);

Quit(0);